UpdateAMP.bat Script füt Windows um AMP zu aktualisieren...

Das folgende Batch-Skript ist ein Community-Skript, mit dem du den Aktualisierungsvorgang unter Windows automatisieren kannst.

Um es zu verwenden, speicherst du das Skript einfach als Stapeldatei (z. B. UpdateAMP.bat) und führst es aus.

Code:

@echo off
rem Script to update AMP Instance Manager and ADS
rem Save as a batch file (such as UpdateAMP.bat) and run as the AMP user in a Command Prompt or Powershell Terminal

echo.
echo Updating AMP...
echo All AMP processes will first be stopped
set /p answer=Continue? (Y/n):
if /i "%answer%"=="n" (
    echo Aborting
    exit 0
)

ampinstmgr stopall
sc query "AMP-ADS01" | findstr /I "RUNNING" >nul
if %errorlevel%==0 (
    net stop "AMP-ADS01"
)

echo.
echo A new AMP installer will now be downloaded and run
echo ADS will then be updated
set /p answer=Continue? (Y/n):
if /i "%answer%"=="n" (
    echo Restarting AMP and aborting
    ampinstmgr start ADS
    exit 0
)

powershell -Command "$ProgressPreference='SilentlyContinue'; wget -O AMPSetup.msi https://cdn-downloads.c7rs.com/AMP/Mainline/AMPSetup.msi"
msiexec /i "AMPSetup.msi" WIXUI_EXITDIALOGOPTIONALCHECKBOX=1

rem On Windows Server, ADS needs to be updated via an Administrator shell
for /f %%i in ('powershell -NoProfile -Command ^
  "((Get-CimInstance -ClassName Win32_OperatingSystem).ProductType)"') do set "ProductType=%%i"

if "%ProductType%"=="1" (
    ampinstmgr upgradeall
) else (
    powershell -Command "Start-Process 'ampinstmgr' -ArgumentList 'upgradeall' -Verb RunAs -Wait"
)

ampinstmgr start ADS

echo.
echo AMP Instance Manager and ADS have now been updated
echo Log in to AMP and click "Update All" to update all other instances and Generic module instance configurations
echo Otherwise each instance and its configuration will be updated when next started

So sollest du für die Zukunft keine Problme mehr haben um dein AMP abzudaten.

LG

rumpel